; PSXKey V2.04
; (c)2000 Double Dutch Designs Limited
; Written by Anthony Ball

; Requires 8Mhz AVR AT90xxxx

; Keyboard optional commands, needs 'off', 'sleep', 'on' keys
; off		keyboard emulates pad
; sleep		keyboard is pad as well as stick inputs
; on		keyboard acts as keyboard - along with stick inputs!

; List of changes:
; 1.xx-2.00	change from pic to avr microcontroller, serial to pad ports
; 2.00-2.01	automatic keyboard detection
; 2.01-2.02	multiplexed sega stick input(s)
; 2.02-2.03	pad emulation via keyboard
; 2.03-2.04	crystal & software change from 4Mhz to 8Mhz

; Limitations:
; o	Will not function properly with a multitap, this is because of the
;	packet length being too long

; Known Bugs:
; o	Memory cards plugged into same port will not function properly

; Features:
; o	Hardware decode/encode of psx communication data
; o	'On-the-fly' detection & reset of inserted keyboard
; o	Interrupt driven keyboard reading
; o	Converts keyboard data to single byte for press, another for depress
; o	Interrupt driven keyboard control
; o	Spurious bit error correction on keyboard data
; o	Parity bit checking on keyboard data
; o	Multiplexed Sega stick input(s)
; o 	Psx pad emulation via keyboard

		.include	"4414def.inc"
;		.include	"2333def.inc"

		.equ	Version=1	; version number

		.def	DataInput=R0	; data from program
		.def	Parity=R1	; parity check
		.def	LastKey=R2	; character for keyboard

		.def	BufferA0=R4
		.def	BufferA1=R5
		.def	BufferA2=R6
		.def	BufferA3=R7
		.def	BufferA4=R8
		.def	BufferA5=R9
		.def	BufferB0=R10
		.def	BufferB1=R11
		.def	BufferB2=R12
		.def	BufferB3=R13
		.def	BufferB4=R14
		.def	BufferB5=R15

		.def	Psx=R16		; psx last chr read, chr to write
		.def	ScratchA=R17	; temp register a
		.def	ScratchB=R18	; temp register b
		.def	ScratchC=R19	; temp register c
		.def	Count=R20	; counter
		.def	IScratch=R21	; interrupt temp register
		.def	ProcessKey=R22	; current key being processed
		.def	Mode=R23	; mode flag
		.def	Dir=R24		; transfer direction
		.def	Break=R25	; break flag
		.def	Release=R26	; release flag
		.def	Enhanced=R27	; enhanced flag
		.def	LockStatus=R28	; key lock status
		.def	IScratch2=R29	; interrupt scratch register 2

		.equ	SCROLL=0	; scroll lock on
		.equ	NUM=1		; num lock on
		.equ	CAPS=2		; caps lock on
		.equ	DONETEST=3	; keyboard has just done a selftest
		.equ	EMUA=4		; emulation mode a
		.equ	EMUB=5		; emulation mode b

		.equ	STICKA0=4	; user programmable stick status
		.equ	STICKA1=5
		.equ	STICKB0=6
		.equ	STICKB1=7

		.equ	IOSetLED=$ed
		.equ	IOScanCode=$f0
		.equ	IOEnable=$f4
		.equ	IOReset=$fe
		.equ	IOAck=$f4	; okay responce
		.equ	IOSelfTest=$aa	; selftest performed okay
		.equ	IOFailA=$00
		.equ	IOFailB=$ff

		.equ	TimeOut=1200	; timeout value for counter
		.equ	Key_Id=$e	; keyboard id
		.equ	Pad_Id=$4	; pad id, emulate standard pad

		.equ	KEYCLK=2	; keyboard clock, out
		.equ	KEYDAT=3	; keyboard data, bi
		.equ	ACK=6		; psx ack, out
		.equ	ATT=4		; psx att, in
		.equ	CMD=5		; psx cmd, in
		.equ	DAT=6		; psx dat, out
		.equ	CLK=7		; psx clk, in

		.equ	Plex=5		; multiplex select
		.equ	Stick1Up=0	; stick udlr, plex has to be 1
		.equ	Stick1Down=1
		.equ	Stick1Left=2
		.equ	Stick1Right=3
		.equ	Stick1A=1	; with plex=0
		.equ	Stick1B=1	; with plex=1
		.equ	Stick1C=4	; with plex=1
		.equ	Stick1START=4	; with plex=0
		.equ	Stick2Up=0	; stick udlr, plex has to be 1
		.equ	Stick2Down=1
		.equ	Stick2Left=2
		.equ	Stick2Right=3
		.equ	Stick2A=1	; with plex=0
		.equ	Stick2B=1	; with plex=1
		.equ	Stick2C=4	; with plex=1
		.equ	Stick2START=4	; with plex=0
		.equ	StickPower=0
		.equ	PadUp=4		; psx pad udlr
		.equ	PadDown=6
		.equ	PadLeft=7
		.equ	PadRight=5
		.equ	PadSelect=0	; select
		.equ	PadX=6		; x
		.equ	PadO=5		; o
		.equ	PadStart=3	; start
		.equ	PadT=4		; triangle
		.equ	PadS=7		; square
		.equ	PadL1=2		; left 1
		.equ	PadR1=3		; right 1
		.equ	PadL2=0		; left 2
		.equ	PadR2=1		; right 2

		.equ	PadAHi=$60	; psx pad a layout pt1
		.equ	PadALo=$61	; psx pad a layout pt2
		.equ	PadBHi=$62	; psx pad b layout pt1
		.equ	PadBLo=$63	; psx pad b layout pt2
		.equ	PadCHi=$64	; psx pad c layout pt1
		.equ	PadCLo=$65	; psx pad c layout pt2
		.equ	PadDHi=$66	; psx pad d layout pt1
		.equ	PadDLo=$67	; psx pad d layout pt2

		.cseg
		.org	0
Reset:		rjmp	Start		; run init
		rjmp	Interrupt	; external int0
		rjmp	Start		; not used (int1)
		rjmp	Start		; not used (capture event)

Timer:		cpi	Dir,1
		breq	StartOutput
		cbi	DDRD,KEYDAT	; data input
		clr	Count		; timer match
		reti
StartOutput:	sbi	DDRD,KEYDAT	; data output
		cbi	PORTD,KEYDAT	; data low (start bit)
		sbi	PORTD,KEYCLK	; clock high
		cbi	DDRD,KEYCLK	; clock input
		clr	Parity		; init parity
		ldi	Count,1
		reti
Interrupt:	cpi	Count,0
		breq	IStart
		cpi	Count,9
		breq	IParity
		cpi	Count,10
		breq	IStop
		cpi	Dir,0
		brne	ITx
		lsr	ProcessKey	; shift key right
		sbis	PIND,KEYDAT
		rjmp	IExit
		sbr	ProcessKey,(1<<7)
		inc	Parity
		rjmp	IExit
ITx:		lsr	ProcessKey	; shift key left
		brcc	ITxSkip1
		sbi	PORTD,KEYDAT	; send a 1
ITxSkip1:	brcs	ITxSkip0
		cbi	PORTD,KEYDAT	; send a 0
ITxSkip0:	rjmp	IExit
IStart:		clr	Parity		; init parity
		sbic	PIND,KEYDAT	; start bit should be low
		rjmp	IError		; start bit is high!!! error...
		rjmp	IExit
IParity:	cpi	Dir,0
		brne	ITxParity
		clr	IScratch
		sbis	PIND,KEYDAT	; get parity bit in iscratch
		ldi	IScratch,1
		eor	IScratch,Parity	; is it the same as calculated?
		andi	IScratch,1
		breq	IExit		; same!		
		cpi	ProcessKey,IOAck
		breq	IExit
		rjmp	IError
ITxParity:	mov	IScratch,Parity
		andi	IScratch,1
		brne	ITxParity1
		cbi	PORTD,KEYDAT	; pull low
		rjmp	IExit
ITxParity1:	sbi	PORTD,KEYDAT	; pull high
		rjmp	IExit
IExit:		inc	Count
IExit2:		clr	IScratch
		out	TCNT1H,IScratch	; reset counter
		out	TCNT1L,IScratch
		reti
ModeLedNo:	mov	ProcessKey,LockStatus
		andi	ProcessKey,$7
		rjmp	IOut
ModeLed:	ldi	ProcessKey,IOSetLED
		rjmp	IOut
ModeSetNo:	ldi	ProcessKey,$02
		rjmp	IOut
ModeSet:	ldi	ProcessKey,IOScanCode
		rjmp	IOut
ModeEnable:	ldi	ProcessKey,IOEnable
		rjmp	IOut
ModeReset:	ldi	ProcessKey,IOReset
		clr	Break		; break key flag
		clr	Release		; release key flag
		clr	Enhanced	; enhanced key flag
		rjmp	IOut
IOut:		sbi	DDRD,KEYCLK	; clock output
		cbi	PORTD,KEYCLK	; clock low
		ldi	Dir,1		; direction 1
INext:		dec	Mode		; next mode!!!
IError:		clr	Count		; reset count for next time
		rjmp	IExit2
IStop:		cpi	Dir,0
		brne	ITxStop
		sbis	PIND,KEYDAT	; stop bit should be high
		rjmp	IError		; start bit is low!!! error...
		cpi	ProcessKey,IOAck
		breq	IOkay
		cpi	ProcessKey,IOFailA
		breq	IBad
		cpi	ProcessKey,IOFailB
		breq	IBad
		cpi	ProcessKey,IOSelfTest
		brne	IStore
		ori	LockStatus,1<<DONETEST
		ldi	Mode,9		; power has been affected!
		ldi	ProcessKey,$7f
		rjmp	Insert
IStore:		cpi	Break,0
		breq	SkipBreak
		dec	Break
		rjmp	IError
SkipBreak:	cpi	ProcessKey,$e1
		brne	NotBreak
		ldi	Break,7
		ldi	ProcessKey,$7e
		rjmp	Insert
NotBreak:	cpi	ProcessKey,$f0	; release key?
		brne	NotRelease
		ldi	Release,$80	; release flag
		rjmp	IError
NotRelease:	cpi	ProcessKey,$e0	; enhanced
		brne	NotEnhanced
		ldi	Enhanced,$01	; enhanced flag
		rjmp	IError
ITxStop:	sbi	PORTD,KEYDAT	; pull high
		clr	Dir
IOkay:		cpi	Mode,0		; IError
		breq	IError
		cpi	Mode,1
		breq	ModeLedNo
		cpi	Mode,3
		breq	ModeLed
		cpi	Mode,5
		breq	ModeEnable
		cpi	Mode,6
		breq	ModeSetNo
		cpi	Mode,8
		breq	ModeSet
		cpi	Mode,9
		breq	ModeReset
		rjmp	INext
IBad:		ldi	Mode,9		; keyboard failure!!!
		rjmp	IOkay
NotEnhanced:	cpi	ProcessKey,$83	; only key over $7f
		brne	Not83
		ldi	ProcessKey,$7f
Not83:		andi	ProcessKey,$7f
		ldi	ZH,high(2*KeyTable) ; load high part of byte address into ZH
		ldi	ZL,low(2*KeyTable) ; load low part of byte address into ZL
		tst	Enhanced
		breq	NotExtended
		ldi	ZH,high(2*Extended) ; load high part of byte address into ZH
		ldi	ZL,low(2*Extended) ; load low part of byte address into ZL
NotExtended:	clr	IScratch
		add	ZL,ProcessKey
		adc	ZH,IScratch
		lpm			; load byte from memory
		mov	ProcessKey,DataInput
		or	ProcessKey,Release
		clr	Enhanced
		clr	Release
Insert:		cpi	ProcessKey,$7d
		brne	NotNormal
		cbr	LockStatus,(1<<EMUA)+(1<<EMUB)
NotNormal:	cpi	ProcessKey,$7c
		brne	NotEmuA
		cbr	LockStatus,(1<<EMUB)
		sbr	LockStatus,(1<<EMUA)
		ser	IScratch
		sts	PadAHi,IScratch
		sts	PadALo,IScratch
NotEmuA:	cpi	ProcessKey,$7b
		brne	NotEmuB
		cbr	LockStatus,(1<<EMUA)
		sbr	LockStatus,(1<<EMUB)
		ser	IScratch
		sts	PadAHi,IScratch
		sts	PadALo,IScratch
NotEmuB:	mov	IScratch,LockStatus
		andi	IScratch,$f0
		breq	NotEmuAB
		rcall	EmulateAB
NotEmuAB:	cpi	ProcessKey,$80	; skip release invalid
		breq	IOkay
		cpi	ProcessKey,0	; skip invalid
		breq	IOkay
		cpi	ProcessKey,$3b	; is it CAPS?
		brne	NotCaps
		ldi	IScratch,1<<CAPS
		eor	LockStatus,IScratch
		ldi	Mode,3
NotCaps:	cpi	ProcessKey,$67	; is it NUM?
		brne	NotNum
		ldi	IScratch,1<<NUM
		eor	LockStatus,IScratch
		ldi	Mode,3
NotNum:		cpi	ProcessKey,$1f	; is it SCROLL?
		brne	NotScroll
		ldi	IScratch,1<<SCROLL
		eor	LockStatus,IScratch
		ldi	Mode,3
NotScroll:	mov	BufferA5,BufferA4
		mov	BufferA4,BufferA3
		mov	BufferA3,BufferA2
		mov	BufferA2,BufferA1
		mov	BufferA1,BufferA0
		mov	BufferA0,ProcessKey
		rjmp	IOkay

EmulateAB:	lds	IScratch,PadAHi
		lds	IScratch2,PadALo
		cpi	ProcessKey,$63
		brne	ENSUp
		cbr	IScratch,(1<<PadUp)
		rjmp	EDone
ENSUp:		cpi	ProcessKey,$63+$80
		brne	ENCUp
		sbr	IScratch,(1<<PadUp)
		rjmp	EDone
ENCUp:		cpi	ProcessKey,$64
		brne	ENSDown
		cbr	IScratch,(1<<PadDown)
		rjmp	EDone
ENSDown:	cpi	ProcessKey,$64+$80
		brne	ENCDown
		sbr	IScratch,(1<<PadDown)
		rjmp	EDone
ENCDown:	cpi	ProcessKey,$65
		brne	ENSLeft
		cbr	IScratch,(1<<PadLeft)
		rjmp	EDone
ENSLeft:	cpi	ProcessKey,$65+$80
		brne	ENCLeft
		sbr	IScratch,(1<<PadLeft)
		rjmp	EDone
ENCLeft:	cpi	ProcessKey,$66
		brne	ENSRight
		cbr	IScratch,(1<<PadRight)
		rjmp	EDone
ENSRight:	cpi	ProcessKey,$66+$80
		brne	ENCRight
		sbr	IScratch,(1<<PadRight)
		rjmp	EDone
ENCRight:	cpi	ProcessKey,$0d
		brne	ENSStart
		cbr	IScratch,(1<<PadStart)
		rjmp	EDone
ENSStart:	cpi	ProcessKey,$0d+$80
		brne	ENCStart
		sbr	IScratch,(1<<PadStart)
		rjmp	EDone
ENCStart:	cpi	ProcessKey,$20
		brne	ENSSelect
		cbr	IScratch,(1<<PadSelect)
		rjmp	EDone
ENSSelect:	cpi	ProcessKey,$20+$80
		brne	ENCSelect
		sbr	IScratch,(1<<PadSelect)
		rjmp	EDone
ENCSelect:	cpi	ProcessKey,$04
		brne	ENSX
		cbr	IScratch2,(1<<PadX)
		rjmp	EDone
ENSX:		cpi	ProcessKey,$04+$80
		brne	ENCX
		sbr	IScratch2,(1<<PadX)
		rjmp	EDone
ENCX:		cpi	ProcessKey,$02
		brne	ENSO
		cbr	IScratch2,(1<<PadO)
		rjmp	EDone
ENSO:		cpi	ProcessKey,$02+$80
		brne	ENCO
		sbr	IScratch2,(1<<PadO)
		rjmp	EDone
ENCO:		cpi	ProcessKey,$01
		brne	ENST
		cbr	IScratch2,(1<<PadT)
		rjmp	EDone
ENST:		cpi	ProcessKey,$01+$80
		brne	ENCT
		sbr	IScratch2,(1<<PadT)
		rjmp	EDone
ENCT:		cpi	ProcessKey,$06
		brne	ENSS
		cbr	IScratch2,(1<<PadS)
		rjmp	EDone
ENSS:		cpi	ProcessKey,$06+$80
		brne	ENCS
		sbr	IScratch2,(1<<PadS)
		rjmp	EDone
ENCS:		cpi	ProcessKey,$51
		brne	ENSL1
		cbr	IScratch2,(1<<PadL1)
		rjmp	EDone
ENSL1:		cpi	ProcessKey,$51+$80
		brne	ENCL1
		sbr	IScratch2,(1<<PadL1)
		rjmp	EDone
ENCL1:		cpi	ProcessKey,$41
		brne	ENSL2
		cbr	IScratch2,(1<<PadL2)
		rjmp	EDone
ENSL2:		cpi	ProcessKey,$41+$80
		brne	ENCL2
		sbr	IScratch2,(1<<PadL2)
		rjmp	EDone
ENCL2:		cpi	ProcessKey,$57
		brne	ENSR1
		cbr	IScratch2,(1<<PadR1)
		rjmp	EDone
ENSR1:		cpi	ProcessKey,$57+$80
		brne	ENCR1
		sbr	IScratch2,(1<<PadR1)
		rjmp	EDone
ENCR1:		cpi	ProcessKey,$53
		brne	ENSR2
		cbr	IScratch2,(1<<PadR2)
		rjmp	EDone
ENSR2:		cpi	ProcessKey,$53+$80
		brne	ENCR2
		sbr	IScratch2,(1<<PadR2)
		rjmp	EDone
ENCR2:		
EDone:		sts	PadAHi,IScratch
		sts	PadALo,IScratch2
		clr	ProcessKey
		ret

Start:		ldi	ScratchA,high(RAMEND) ; high byte only required if 
		out	SPH,ScratchA	; RAM is bigger than 256 Bytes
		ldi	ScratchA,low(RAMEND)	 
		out	SPL,ScratchA

		ldi	ScratchA,(1<<ACK)+(1<<KEYCLK)+(1<<KEYDAT)+$f ;all have pull-ups
		out	PORTD,ScratchA	; default is hi
		ldi	ScratchA,(1<<ACK)+(1<<StickPower)+(1<<Plex)
		out	DDRD,ScratchA	; init ACK & keyboard CLK

		ldi	ScratchA,$0f	; all have pull-ups
		out	PORTB,ScratchA		
		ldi	ScratchA,1<<DAT
		out	DDRB,ScratchA

		clr	BufferA0
		clr	BufferA1
		clr	BufferA2
		clr	BufferA3
		clr	BufferA4
		clr	BufferA5
		clr	BufferB0
		clr	BufferB1
		clr	BufferB2
		clr	BufferB3
		clr	BufferB4
		clr	BufferB5

		ser	ScratchA
		sts	PadAHi,ScratchA
		sts	PadALo,ScratchA	
		sts	PadBHi,ScratchA
		sts	PadBLo,ScratchA
		sts	PadCHi,ScratchA
		sts	PadCLo,ScratchA
		sts	PadDHi,ScratchA
		sts	PadDLo,ScratchA

		clr	Count		; start counter for keyboard
		clr	Break		; break key flag
		clr	Release		; release key flag
		clr	Enhanced	; enhanced key flag

		ldi	LockStatus,(1<<NUM) ; num lock on!

		ldi	ScratchA,(1<<ISC01) ; interrupt on falling edge
		out	MCUCR,ScratchA
		ldi	ScratchA,(1<<INT0) ; turn keyboard interrupt on
		out	GIMSK,ScratchA
		ldi	ScratchA,(1<<OCIE1A) ; timer compare on
		out	TIMSK,ScratchA
		ldi	ScratchA,high(TimeOut) ; timeout compare value
		out	OCR1AH,ScratchA
		ldi	ScratchA,low(TimeOut)	 
		out	OCR1AL,ScratchA
		ldi	ScratchA,(1<<CS12) ; interrupt count amount (CK)
		out	TCCR1B,ScratchA
		clr	Dir		; input to start
		ldi	Mode,9		; reset keyboard, setup my settings
		sei			; interrupts enabled

		ldi	ScratchA,(1<<DORD)+(1<<CPOL)+(1<<CPHA)+(1<<SPE)
		out	SPCR,ScratchA	; start the spi port
		
Loop:		rcall	GetPadB		; get joypad 1 values
		rcall	GetPadC		; get joypad 2 values
		rcall	GetPadD		; get joypad 3 values
		sbrc	LockStatus,EMUB ; emulate mode b?
		rjmp	Emulator
		rcall	TransferBuffer	; transfer buffers
		rcall	KeyPacket	; send data to psx
		rjmp	Loop
Emulator:	rcall	PadPacket
		rjmp	Loop

KeyPacket:	sbic	PINB,ATT	; my turn?
		rjmp	KeyPacket	; nope!

		rcall	SPI_Read
		cpi	Psx,$01		; has the psx sent a $01
		brne	KeyPacket	; nope! out of sync, try again
		ldi	Psx,(Key_Id<<4)+$8 ; id & no. words
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		cpi	Psx,$42		; has the psx sent a $42
		brne	KeyPacket	; nope! out of sync!!!!  try again
		ldi	Psx,$5a		; data will follow!
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadAHi	; word 1, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadALo	; word 1, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadBHi	; word 2, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadBLo	; word 2, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadCHi	; word 3, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadCLo	; word 3, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadDHi	; word 4, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadDLo	; word 4, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		ldi	Psx,Version	; word 5, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,LockStatus	; word 5, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck


		rcall	SPI_Read
		mov	Psx,BufferB0	; word 6, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,BufferB1	; word 6, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,BufferB2	; word 7, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,BufferB3	; word 7, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,BufferB4	; word 8, high
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		mov	Psx,BufferB5	; word 8, low
		rcall	SPI_Write
		sbic	PINB,ATT	; error?
		rjmp	KeyPacket	; yep!
		rcall	SendAck

		andi	LockStatus,$f7
Wait:		sbis	PINB,ATT	; finished?
		rjmp	Wait		; nope!
		ret

PadPacket:	sbic	PINB,ATT	; my turn?
		rjmp	PadPacket	; nope!

		rcall	SPI_Read
		cpi	Psx,$01		; has the psx sent a $01
		brne	PadPacket	; nope! out of sync, try again
		ldi	Psx,(Pad_Id<<4)+1 ; id & no. words
		rcall	SPI_Write

		sbic	PINB,ATT	; error?
		rjmp	PadPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		cpi	Psx,$42		; has the psx sent a $42
		brne	PadPacket	; nope! out of sync!!!!  try again
		ldi	Psx,$5a		; data will follow!
		rcall	SPI_Write

		sbic	PINB,ATT	; error?
		rjmp	PadPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadAHi	; word 1, high
		rcall	SPI_Write

		sbic	PINB,ATT	; error?
		rjmp	PadPacket	; yep!
		rcall	SendAck

		rcall	SPI_Read
		lds	Psx,PadALo	; word 1, low
		rcall	SPI_Write

		sbic	PINB,ATT	; error turn?
		rjmp	PadPacket	; yep!
		rcall	SendAck

		rjmp	Wait		; wait for end!!!

; get stick 1 inputs, convert to nearest pad layout
GetPadB:	ser	ScratchB
		ser	ScratchC
		in	ScratchA,PINB	; read UDLR
		sbrs	ScratchA,Stick1Up ; up?
		cbr	ScratchB,(1<<PadUp)
		sbrs	ScratchA,Stick1Down ; down?
		cbr	ScratchB,(1<<PadDown)
		sbrs	ScratchA,Stick1Left ; left?
		cbr	ScratchB,(1<<PadLeft)
		sbrs	ScratchA,Stick1Right ; right?
		cbr	ScratchB,(1<<PadRight)
		in	ScratchA,PIND	; read B/C
		cbi	PORTD,Plex	; do multiplexed inputs
		sbrs	ScratchA,Stick1B ; b?
		cbr	ScratchC,(1<<PadX)
		sbrs	ScratchA,Stick1C ; c?
		cbr	ScratchC,(1<<PadO)
		in	ScratchA,PIND	; read START/A
		sbi	PORTD,Plex	; set again for future read
		sbrs	ScratchA,Stick1A ; a?
		cbr	ScratchB,(1<<PadSelect)
		sbrs	ScratchA,Stick1Start ; start?
		cbr	ScratchB,(1<<PadStart)
		sts	PadBHi,ScratchB
		sts	PadBLo,ScratchC
		ret

; get stick a inputs, convert to nearest pad layout
GetPadC:	ser	ScratchB
		ser	ScratchC
		in	ScratchA,PINB	; read UDLR
		sbrs	ScratchA,Stick2Up ; up?
		cbr	ScratchB,(1<<PadUp)
		sbrs	ScratchA,Stick2Down ; down?
		cbr	ScratchB,(1<<PadDown)
		sbrs	ScratchA,Stick2Left ; left?
		cbr	ScratchB,(1<<PadLeft)
		sbrs	ScratchA,Stick2Right ; right?
		cbr	ScratchB,(1<<PadRight)
		in	ScratchA,PIND	; read B/C
		cbi	PORTD,Plex	; do multiplexed inputs
		sbrs	ScratchA,Stick2B ; b?
		cbr	ScratchC,(1<<PadX)
		sbrs	ScratchA,Stick2C ; c?
		cbr	ScratchC,(1<<PadO)
		in	ScratchA,PIND	; read START/A
		sbi	PORTD,Plex	; set again for future read
		sbrs	ScratchA,Stick2A ; a?
		cbr	ScratchB,(1<<PadSelect)
		sbrs	ScratchA,Stick2Start ; start?
		cbr	ScratchB,(1<<PadStart)
		sts	PadCHi,ScratchB
		sts	PadCLo,ScratchC
		ret

; get extra joystick on pro unit
GetPadD:	ser	ScratchA
		sts	PadDHi,ScratchA
		sts	PadDLo,ScratchA
		ret

; sends an ack to the psx
SendACK:	nop
		nop
		nop
		nop
		nop
		nop
		nop
		nop
		nop
		nop
		cbi	PORTD,ACK	; pull low
		nop
		sbi	PORTD,ACK	; high again!!!
		ret

; read 'psx' from the spi port
SPI_Read:	sbis	SPSR,SPIF	; is transfer complete?
		rjmp	SPI_Read	; nope!
		in	Psx,SPDR
		ret

; wait until read completed
SPI_Wait:	sbis	SPSR,SPIF	; is transfer complete?
		rjmp	SPI_Wait	; nope!
		ret

; write 'psx' to the spi port
SPI_Write:	out	SPDR,Psx
		sbic	SPSR,WCOL
		rjmp	SPI_Write
		ret

TransferBuffer:	cli
		mov	BufferB0,BufferA0
		mov	BufferB1,BufferA1
		mov	BufferB2,BufferA2
		mov	BufferB3,BufferA3
		mov	BufferB4,BufferA4
		mov	BufferB5,BufferA5
		clr	BufferA0
		clr	BufferA1
		clr	BufferA2
		clr	BufferA3
		clr	BufferA4
		clr	BufferA5
		sei
		ret

KeyTable:	.db	$00,$19	; 01
		.db	$00,$15	; 03
		.db	$13,$11	; 05
		.db	$12,$1c	; 07
		.db	$00,$1a	; 09
		.db	$18,$16	; 0b
		.db	$14,$27	; 0d
		.db	$60,$00	; 0f
		.db	$00,$06	; 11
		.db	$02,$00	; 13
		.db	$04,$51	; 15
		.db	$21,$00	; 17
		.db	$00,$00	; 19
		.db	$5a,$53	; 1b
		.db	$41,$57	; 1d
		.db	$22,$00	; 1f
		.db	$00,$43	; 21
		.db	$58,$44	; 23
		.db	$45,$24	; 25
		.db	$68,$00	; 27
		.db	$00,$20	; 29
		.db	$56,$46	; 2b
		.db	$54,$52	; 2d
		.db	$25,$00	; 2f
		.db	$00,$4e	; 31
		.db	$42,$48	; 33
		.db	$47,$59	; 35
		.db	$5e,$00	; 37
		.db	$00,$00	; 39
		.db	$4d,$4a	; 3b
		.db	$55,$26	; 3d
		.db	$2a,$00	; 3f
		.db	$00,$3c	; 41
		.db	$4b,$49	; 43
		.db	$4f,$29	; 45
		.db	$28,$00	; 47
		.db	$00,$3e	; 49
		.db	$3f,$4c	; 4b
		.db	$3a,$50	; 4d
		.db	$5f,$00	; 4f
		.db	$00,$00	; 51
		.db	$40,$00	; 53
		.db	$5b,$3d	; 55
		.db	$00,$00	; 57
		.db	$3b,$03	; 59
		.db	$0d,$5d	; 5b
		.db	$00,$23	; 5d
		.db	$00,$00	; 5f
		.db	$00,$5c	; 61
		.db	$00,$00	; 63
		.db	$00,$00	; 65
		.db	$2c,$00	; 67
		.db	$00,$31	; 69
		.db	$00,$34	; 6b
		.db	$37,$00	; 6d
		.db	$00,$00	; 6f
		.db	$30,$2e	; 71
		.db	$32,$35	; 73
		.db	$36,$38	; 75
		.db	$01,$67	; 77
		.db	$1b,$2b	; 79
		.db	$33,$2d	; 7b
		.db	$1e,$39	; 7d
		.db	$1f,$17	; 7f (was 83)
Extended:	.db	$00,$00	; 01
		.db	$00,$00	; 03
		.db	$00,$00	; 05
		.db	$00,$00	; 07
		.db	$00,$00	; 09
		.db	$00,$00	; 0b
		.db	$00,$00	; 0d
		.db	$00,$00	; 0f
		.db	$00,$07	; 11
		.db	$00,$00	; 13
		.db	$0a,$00	; 15
		.db	$00,$00	; 17
		.db	$00,$00	; 19
		.db	$00,$00	; 1b
		.db	$00,$00	; 1d
		.db	$00,$05	; 1f
		.db	$00,$00	; 21
		.db	$00,$00	; 23
		.db	$00,$00	; 25
		.db	$00,$08	; 27
		.db	$00,$00	; 29
		.db	$00,$00	; 2b
		.db	$00,$00	; 2d
		.db	$00,$09	; 2f
		.db	$00,$00	; 31
		.db	$00,$00	; 33
		.db	$00,$00	; 35
		.db	$00,$7b	; 37
		.db	$00,$00	; 39
		.db	$00,$00	; 3b
		.db	$00,$00	; 3d
		.db	$00,$7c	; 3f
		.db	$00,$00	; 41
		.db	$00,$00	; 43
		.db	$00,$00	; 45
		.db	$00,$00	; 47
		.db	$00,$00	; 49
		.db	$2f,$00	; 4b
		.db	$00,$00	; 4d
		.db	$00,$00	; 4f
		.db	$00,$00	; 51
		.db	$00,$00	; 53
		.db	$00,$00	; 55
		.db	$00,$00	; 57
		.db	$00,$00	; 59
		.db	$0c,$00	; 5b
		.db	$00,$00	; 5d
		.db	$7d,$00	; 5f
		.db	$00,$00	; 61
		.db	$00,$00	; 63
		.db	$00,$00	; 65
		.db	$00,$00	; 67
		.db	$00,$61	; 69
		.db	$00,$65	; 6b
		.db	$0e,$00	; 6d
		.db	$00,$00	; 6f
		.db	$0b,$10	; 71
		.db	$64,$00	; 73
		.db	$66,$63	; 75
		.db	$00,$00	; 77
		.db	$00,$00	; 79
		.db	$62,$00	; 7b
		.db	$1d,$0f	; 7d
		.db	$00,$00	; 7f

		.eseg
		.org	0
		.db	"This is for Faye!!!  I love you!!!"